使用Terraform创建、查询和删除Kafka实例_云消息队列 Kafka 版(Kafka)-阿里云帮助中心

Terraform的alicloud_alikafka_instance资源提供一系列参数来管理Kafka实例，使用Terraform自动创建、部署实例可以缩短部署时间，保证多个环境的配置一致性，减少人为操作，降低引入错误的概率。

说明

本教程所含示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式请参见创建RAM用户和创建AccessKey。

通过RAM授权，阿里云用户可以有效地管理其云资源访问权限，适应多用户协同工作的需求，并且能够按需为用户分配最小权限，避免权限过大导致的安全漏洞‌。具体操作方式请参见为RAM用户授权。

{
    "Version": "1",
    "Statement": [
        {
            "Effect": "Allow",
            "Action": [
                "vpc:DescribeVpcAttribute",
                "vpc:DescribeRouteTableList",
                "vpc:DescribeVSwitchAttributes",
                "vpc:DeleteVpc",
                "vpc:DeleteVSwitch",
                "vpc:CreateVpc",
                "vpc:CreateVSwitch"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": "bss:ModifyAgreementRecord",
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "bss:DescribeOrderList",
                "bss:DescribeOrderDetail",
                "bss:PayOrder",
                "bss:CancelOrder"
            ],
            "Resource": "*"
        },
        {
            "Effect": "Allow",
            "Action": [
                "ecs:CreateSecurityGroup",
                "ecs:ModifySecurityGroupPolicy",
                "ecs:DescribeSecurityGroups",
                "ecs:ListTagResources",
                "ecs:DeleteSecurityGroup",
                "ecs:DescribeSecurityGroupAttribute",
                "ecs:AuthorizeSecurityGroup",
                "ecs:RevokeSecurityGroup"
            ],
            "Resource": "*"
        },
        {
            "Action": "alikafka:*",
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": [
                        "connector.alikafka.aliyuncs.com",
                        "instanceencryption.alikafka.aliyuncs.com",
                        "alikafka.aliyuncs.com",
                        "etl.alikafka.aliyuncs.com"
                    ]
                }
            }
        }
    ]
}

准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。
- 在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。
- Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。
- 在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

使用的资源

说明

本教程示例包含的部分资源会产生一定费用，请在不需要时及时进行释放或退订。

alicloud_vpc：创建一个专有网络VPC。
alicloud_vswitch：创建一个专有网络交换机。
alicloud_security_group：创建一个安全组。
alicloud_alikafka_instance：创建一个Kafka实例。
alicloud_alikafka_instances：查询Kafka实例。

创建并部署实例

说明

目前不支持通过Terraform删除预付费实例。

本示例以在华南1（深圳）地域下创建流量规格为alikafka.hw.2xlarge的VPC Kafka实例为例，实例名称为alikafkaInstanceName。

创建一个工作目录，并在该工作目录中创建名为main.tf的配置文件，然后将以下代码复制到main.tf中。

variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

# 创建VPC
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建安全组。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# 创建实例，磁盘类型为高效云盘，磁盘容量为500 GB，流量规格为alikafka.hw.2xlarge。
# 部署实例。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

执行以下命令，初始化Terraform运行环境。

terraform init

返回如下信息，表示Terraform初始化成功。

Initializing the backend...

Initializing provider plugins...
- Checking for available provider plugins...
- Downloading plugin for provider "alicloud" (hashicorp/alicloud) 1.90.1...
...

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other

创建执行计划，并预览变更。
```
terraform plan
```

执行以下命令，创建资源。

terraform apply

在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

...

alicloud_alikafka_instance.default: Destroying... [id=alikafka_post-cn-****]
alicloud_alikafka_instance.default: Still destroying... [id=alikafka_post-cn-****, 10s elapsed]
alicloud_alikafka_instance.default: Destruction complete after 11s
alicloud_security_group.default: Destroying... [id=sg-****]
alicloud_vswitch.vsw: Destroying... [id=vsw-****]
alicloud_security_group.default: Destruction complete after 1s
alicloud_vpc.default: Creating...
alicloud_vswitch.vsw: Destruction complete after 4s
alicloud_vpc.vpc: Destroying... [id=vpc-****]
alicloud_vpc.vpc: Destruction complete after 1s
alicloud_vpc.default: Creation complete after 4s [id=vpc-****]
alicloud_security_group.default: Creating...
alicloud_vswitch.default: Creating...
alicloud_security_group.default: Creation complete after 1s [id=sg-****]
alicloud_vswitch.default: Creation complete after 4s [id=vsw-****]
alicloud_alikafka_instance.default: Creating...
alicloud_alikafka_instance.default: Still creating... [10s elapsed]
...
alicloud_alikafka_instance.default: Creation complete after 3m42s [id=alikafka_post-cn-****]

Apply complete! Resources: 4 added, 0 changed, 0 destroyed.

验证结果。

执行terraform show命令

执行terraform show查看Kafka实例信息。

terraform show

# alicloud_alikafka_instance.default:
resource "alicloud_alikafka_instance" "default" {
    config            = jsonencode(
        {
            "cloud.maxTieredStoreSpace"       = "0"
            "enable.acl"                      = "false"
            "enable.compact"                  = "true"
            "enable.tiered"                   = "false"
            "enable.vpc_sasl_ssl"             = "false"
            "kafka.log.retention.hours"       = "72"
            "kafka.message.max.bytes"         = "1048576"
            "kafka.offsets.retention.minutes" = "10080"
            "kafka.ssl.bit"                   = "1024"
        }
    )
    deploy_type       = 5
    disk_size         = 500
    disk_type         = 0
    eip_max           = 0
    end_point         = "172.16.201.166:9092,172.16.201.167:9092,172.16.201.165:9092"
    group_left        = 2100
    group_used        = 0
    id                = "alikafka_post-cn-jfj40boei007"
    io_max            = 20
    io_max_spec       = "alikafka.hw.2xlarge"
    is_partition_buy  = 1
    kms_key_id        = null
    name              = "alikafkaInstanceName"
    paid_type         = "PostPaid"
    partition_left    = 1050
    partition_num     = 50
    partition_used    = 0
    resource_group_id = "rg-acfmykd63gtpfpa"
    security_group    = "sg-wz95ccy5lzy46acczhsm"
    service_version   = "2.2.0"
    spec_type         = "normal"
    status            = 5
    topic_left        = 1050
    topic_num_of_buy  = 1050
    topic_quota       = 1050
    topic_used        = 0
    vpc_id            = "vpc-wz9gv3xgeoyxte8t4zab0"
    vswitch_id        = "vsw-wz9u6icvx3k1hy2d44emk"
    zone_id           = "zonef"
}

登录云消息队列 Kafka 版控制台

登录云消息队列 Kafka 版控制台，查看Kafka实例信息。

查询实例

以查询云账号下的第一个Kafka实例为例。

在上述main.tf文件中，增加data "alicloud_alikafka_instances" "instances_ds"配置项，具体配置如下。

data "alicloud_alikafka_instances" "instances_ds" {
  output_file = "instances.txt"
}

output "first_instance_name" {
  # 索引[0]在这里表示列表中的第一项。
  value = data.alicloud_alikafka_instances.instances_ds.instances.0.name
}

创建执行计划，并预览变更。
```
terraform plan
```

执行以下命令，创建资源。

terraform apply

在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示运行成功。

alicloud_vpc.default: Refreshing state... [id=vpc-****]
alicloud_security_group.default: Refreshing state... [id=sg-****]
alicloud_vswitch.default: Refreshing state... [id=vsw-****]
alicloud_alikafka_instance.default: Refreshing state... [id=alikafka_post-cn-****]
data.alicloud_alikafka_instances.instances_ds: Reading...
data.alicloud_alikafka_instances.instances_ds: Read complete after 0s [id=****]

Changes to Outputs:
  + first_instance_name = "alikafkaInstanceName"

You can apply this plan to save these new output values to the Terraform state, without changing any real
infrastructure.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes


Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

Outputs:

first_instance_name = "alikafkaInstanceName"

验证结果。

在instances.txt文件中查看实例的其他更多信息。

[
	{
		"config": "{\"enable.vpc_sasl_ssl\":\"false\",\"kafka.log.retention.hours\":\"72\",\"kafka.offsets.retention.minutes\":\"10080\",\"enable.tiered\":\"false\",\"cloud.maxTieredStoreSpace\":\"0\",\"enable.acl\":\"true\",\"kafka.ssl.bit\":\"1024\",\"enable.compact\":\"true\",\"kafka.message.max.bytes\":\"1048576\"}",
		"create_time": 1698908400000,
		"deploy_type": 5,
		"disk_size": 900,
		"disk_type": 0,
		"domain_endpoint": "alikafka-post-cn-uax3go6z****-1-vpc.alikafka.aliyuncs.com:9092,alikafka-post-cn-****-2-vpc.alikafka.aliyuncs.com:9092,alikafka-post-cn-****-3-vpc.alikafka.aliyuncs.com:9092",
		"eip_max": 0,
		"end_point": "192.168.XX.XX:9092,192.168.XX.XX:9092,192.168.XX.XX:9092",
		"expired_time": 2014527600000,
		"id": "alikafka_post-cn-****",
		"io_max": 20,
		"msg_retain": 72,
		"name": "alikafka_post-cn-****",
		"paid_type": "PostPaid",
		"sasl_domain_endpoint": "alikafka-post-cn-****-1-vpc.alikafka.aliyuncs.com:9094,alikafka-post-cn-****-2-vpc.alikafka.aliyuncs.com:9094,alikafka-post-cn-****-3-vpc.alikafka.aliyuncs.com:9094",
		"security_group": "sg-****",
		"service_status": 5,
		"service_version": "2.2.0",
		"spec_type": "professional",
		"ssl_domain_endpoint": null,
		"ssl_end_point": "",
		"tags": {},
		"upgrade_service_detail_info": [
			{
				"current2_open_source_version": "2.2.0"
			}
		],
		"vpc_id": "vpc-****",
		"vswitch_id": "vsw-****",
		"zone_id": "zonek"
	},
]

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

variable "region" {
  default = "cn-shenzhen"
}

variable "instance_name" {
  default = "alikafkaInstanceName"
}

variable "zone_id" {
  default = "cn-shenzhen-f"
}

provider "alicloud" {
  region = var.region
}

# 创建VPC
resource "alicloud_vpc" "default" {
  vpc_name   = "alicloud"
  cidr_block = "172.16.0.0/16"
}

# 创建交换机
resource "alicloud_vswitch" "default" {
  vpc_id     = alicloud_vpc.default.id
  cidr_block = "172.16.192.0/20"
  zone_id    = var.zone_id
}

# 创建安全组。
resource "alicloud_security_group" "default" {
  vpc_id = alicloud_vpc.default.id
}

# 创建实例，磁盘类型为高效云盘，磁盘容量为500 GB，流量规格为alikafka.hw.2xlarge。
# 部署实例。
resource "alicloud_alikafka_instance" "default" {
  name           = var.instance_name
  partition_num  = 50
  disk_type      = 0
  disk_size      = 500
  deploy_type    = 5
  io_max_spec    = "alikafka.hw.2xlarge"
  vswitch_id     = alicloud_vswitch.default.id
  security_group = alicloud_security_group.default.id
}

# 查询实例
data "alicloud_alikafka_instances" "instances_ds" {
  depends_on = [alicloud_alikafka_instance.default]
  output_file = "instances.txt"
}

output "first_instance_name" {
  # 索引[0]在这里表示列表中的第一项。
  value = data.alicloud_alikafka_instances.instances_ds.instances.0.name
}

通过 Terraform 管理 Kafka 实例